home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD014a.dsk / CHRISTMAS PROGRAM.bas < prev    next >
BASIC Source File  |  2003-06-12  |  4KB  |  58 lines
  1. 10  TEXT : HOME 
  2. 20  GOTO 999
  3. 40  HTAB  INT(21 - LEN(A$)/2): PRINT A$: RETURN 
  4. 50  HOME : FOR I = 1 TO 40: VTAB 1: INVERSE : HTAB I: PRINT " ": VTAB 21: HTAB I: PRINT " ": NEXT I
  5. 60  FOR I = 1 TO 21: VTAB I: HTAB 1: PRINT " ": VTAB I: HTAB 40: PRINT " ": NEXT I
  6. 70  NORMAL : RETURN 
  7. 80  POKE  -16368,0: VTAB 20: HTAB 7: PRINT ".....PLEASE PRESS A KEY.....": WAIT  -16384,128: HOME : GOSUB 50: RETURN 
  8. 999  GOSUB 50
  9. 1000  VTAB 5:A$ = "MERRY CHRISTMAS PROGRAM": GOSUB 40
  10. 1020  VTAB 10:A$ = "WRITTEN BY JEFF MARRACCINI": GOSUB 40: GOSUB 80
  11. 1030  VTAB 5:A$ = "IN A MOMENT, A GRAPHICS PICTURE WILL": GOSUB 40:A$ = "APPEAR. ADJUST YOUR MONITOR'S COLOR": GOSUB 40:A$ = "AND TINT SETTINGS TO MATCH THE": GOSUB 40:A$ = "NAMES AND COLORS."
  12. 1031  GOSUB 40
  13. 1035  GOSUB 80
  14. 1040  GR 
  15. 1050  FOR I = 1 TO 9: COLOR= 1: VLIN 0,39 AT I: NEXT I: FOR I = 10 TO 19: COLOR= 3: VLIN 0,39 AT I: NEXT I
  16. 1060  COLOR= 4: FOR I = 20 TO 29: VLIN 0,39 AT I: NEXT I
  17. 1070  COLOR= 6: FOR I = 30 TO 39: VLIN 0,39 AT I: NEXT I
  18. 1080  HOME : VTAB 21: PRINT "INDIAN RED, PINK,   DARK BLUE,BLUE"
  19. 1090  VTAB 22: INVERSE : PRINT "ADJUST YOUR MONITOR, THEN PRESS A KEY...": POKE  -16368,0: WAIT  -16384,128: POKE  -16368,0: NORMAL 
  20. 1100  GR : TEXT : HOME 
  21. 1110  GOSUB 50: VTAB 10:A$ = "...PLEASE WAIT...": GOSUB 40
  22. 1120  PRINT  CHR$(4)"BLOAD PICDRAWF": PRINT  CHR$(4)"BLOAD CHRISTMAS SCENE,A32768": POKE 36352,0: POKE 36353,128: HGR : POKE  -16302,0: CALL 36400
  23. 1130  HOME : POKE  -16301,0: VTAB 21:A$ = "...PLEASE WAIT...": GOSUB 40
  24. 1140  PRINT  CHR$(4)"BLOAD REGULAR PLAYER": PRINT  CHR$(4)"BLOAD MERRY CHRISTMAS,A24576": POKE 30,0: POKE 31,96: POKE  -16302,0: CALL 768
  25. 1141  HOME : POKE  -16301,0: VTAB 21:A$ = "...PLEASE WAIT...": GOSUB 40: POKE  -16368,0
  26. 1142  PRINT  CHR$(4)"BLOAD PLAYER": PRINT  CHR$(4)"BLOAD LET IT SNOW,A24576": POKE 30,0: POKE 31,96: POKE  -16302,0: GOTO 6000
  27. 1150  TEXT : HOME : GOSUB 50: VTAB 10:A$ = "HAVE A MERRY CHRISTMAS,": GOSUB 40:A$ = "AND A HAPPY NEW YEAR!": GOSUB 40: GOSUB 80
  28. 1151  VTAB 5
  29. 1160  POKE 34,1: POKE 35,20: POKE 32,1: POKE 33,38
  30. 1161  HOME :A$ = "CHRISTMAS PROGRAM": FLASH : GOSUB 40: NORMAL : POKE 34,2
  31. 1162  VTAB 20
  32. 1170 A$ = "CREDITS:": GOSUB 40
  33. 1171  SPEED= 100
  34. 1180  PRINT 
  35. 1190  READ A$: IF A$ = ""  THEN  GOTO 2000
  36. 1191  FOR K = 1 TO 050:P =  PEEK( -16336): NEXT K
  37. 1200  GOSUB 40: GOTO 1190
  38. 1300  DATA   "GRAPHICS BY:","GRAPHICS MAGICIAN","FROM PENGUIN SOFTWARE","<CTRL-J>"
  39. 1310  DATA  "SOUND BY:","ELECTRIC DUET","FROM INSOFT","<CTRL-J>"
  40. 1315  DATA  "PROGRAM WRITTEN BY:","JEFF MARRACCINI","5582 DVORAK","CLARKSTON, MICHIGAN 48016","<CTRL-J>","THANKS TO:","<CTRL-J>"
  41. 1316  DATA  "DONNA MARRACCINI,","FOR CONSTRUCTIVE CRITICISM","BRUNO MARRACCINI,","FOR NOT PAYING ATTENTION"
  42. 1318  DATA  "<CTRL-J><CTRL-J><CTRL-J><CTRL-J>","FILMED IN MAGICOLOR.","108 COLOR PALETTE USED.",""
  43. 2000  TEXT : SPEED= 255: GOSUB 80
  44. 2010  HOME : PRINT  CHR$(4)"RUN KICK.IT.OFF"
  45. 6000  PRINT  CHR$(4)"BLOAD PICDRAWF": PRINT  CHR$(4)"BLOAD SNOW,A32768": POKE 36352,0: POKE 36353,128: CALL 36400
  46. 6001  HCOLOR= 3: ONERR  GOTO 6010
  47. 6002 I = 192: CALL 768
  48. 6003 I = I -1: IF I >0  THEN  HPLOT 0,I TO 279,I: CALL 789
  49. 6010  IF I >0  THEN  GOTO 6003
  50. 6011  ONERR  GOTO 6040
  51. 6012  HOME : VTAB 12: HTAB 11: PRINT "SHOVEL THAT SNOW!"
  52. 6013  VTAB 1: PRINT "-- A TYPICAL MICHIGAN WINTER."
  53. 6014  VTAB 15: PRINT "MOTHER SAYS, "; CHR$(34);"HOW DO YOU EXPECT TO GO TO SCHOOL WITH THE DOORS BLOCKED?"; CHR$(34)
  54. 6015  VTAB 20: PRINT "I SAY, "; CHR$(34);"LET IT SNOW, LET IT SNOW, LET IT SNOW."; CHR$(34)
  55. 6020 I = 1
  56. 6021 I = I +1: IF I <63  THEN  POKE  -16303,0: CALL 789
  57. 6040  IF I <63  THEN 6021
  58. 6050  GOTO 1150